おやじプログラマー日記 : VB.NET:Spreadのテキストセルでバイト数入力制限を掛ける方法

Spreadのテキストセルで入力する文字数をバイト数で制限する方法について、 Shift-JISエンコーディングのバイト配列処理メソッドを使って行います。

バイト数制限というのは、ほぼShift-JISに由来する考え方で、データベースの文字列定義をShift-JISにしておくとオラクルのVARCHAR2のデータ型でもバイト数制限は必要でした。

以下にソースを示しますが、少し説明します。
最初にフォームロード時に、Shift-JISの文字エンコーディングを生成し、 Spreadの編集モードセルのテキスト変更時イベント処理と、データモデルに変更時イベント処理を宣言しています。
また、両方のイベントで使う、文字列の最後の漢字の泣き別れを防ぐ関数導入しました。既に入力された文字が"あいうえ1"の場合に、さらに漢字で"お"と入力されても "お"の文字の前半分が残らない様にしています。

Imports FarPoint.Win.Spread
Public Class Form1
    '文字エンコーディング
    Dim SJIS As System.Text.Encoding
    Dim WithEvents DataModel As Model.DefaultSheetDataModel

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        '文字エンコーディング
        SJIS = System.Text.Encoding.GetEncoding("shift-jis")
        'データモデル
        DataModel = FpSpread1.Sheets(0).Models.Data
        'セルにテキストセルで10文字設定
        Dim TxtCell As New CellType.TextCellType
        TxtCell.MaxLength = 10
        FpSpread1.Sheets(0).Cells(0, 0).CellType = TxtCell
    End Sub

'編集モードセルのテキスト変更時イベント
    Private Sub FpSpread1_EditChange(ByVal sender As Object, ByVal e As EditorNotifyEventArgs) Handles FpSpread1.EditChange
        Try
            If TypeOf (e.View.GetSheetView.ActiveCell.CellType) Is CellType.TextCellType Then
                Dim TxtCell As CellType.TextCellType = e.View.GetSheetView.ActiveCell.CellType
                Dim str As String = e.EditingControl.Text
                '入力テキストが指定バイト数を超えた??
                If SJIS.GetByteCount(str) > TxtCell.MaxLength Then
                    '漢字の泣き別れを加味
                    e.EditingControl.Text = CnvKanjiHalfCut(str, TxtCell.MaxLength, SJIS)
                    '
                    CType(e.EditingControl, CellType.GeneralEditor).SelectionStart = e.EditingControl.Text.Length
                End If
            End If
        Catch
        End Try
    End Sub

'データモデルに変更時イベント
    Private Sub DataModel_Changed(ByVal sender As Object, ByVal e As Model.SheetDataModelEventArgs) Handles DataModel.Changed
        '非編集状態でクリップボードから貼り付けした場合
        If e.Type = Model.SheetDataModelEventType.CellsUpdated Then
            Try
                If TypeOf (FpSpread1.Sheets(0).ActiveCell.CellType) Is CellType.TextCellType Then
                    Dim TxtCell As CellType.TextCellType = FpSpread1.Sheets(0).ActiveCell.CellType
                    Dim str As String = DataModel.GetValue(e.Row, e.Column)
                    '入力テキストが指定バイト数を超えた??
                    If SJIS.GetByteCount(str) > TxtCell.MaxLength Then
                        str = CnvKanjiHalfCut(str, TxtCell.MaxLength, SJIS)
                        DataModel.SetValue(e.Row, e.Column, str)
                    End If
                End If
            Catch
            End Try
        End If
    End Sub

'最終文字が漢字で泣き別れするかチェック
    Private Function CnvKanjiHalfCut(ByVal strSrc As String, ByVal nLen As Integer, ByVal Enc As System.Text.Encoding) As String
        Dim Bytes As Byte() = Enc.GetBytes(strSrc)
        Dim str As String = Enc.GetString(Bytes, 0, nLen)
        If Enc.GetByteCount(str) > nLen Then
            Array.Resize(Bytes, nLen - 1)
            str = Enc.GetString(Bytes)
        End If
        Return str
    End Function
End Class