おやじプログラマー日記: VB.NETのComboBoxに枠線(ボーダー)を表示する様に拡張したクラス(Border/BorderStyle/BorderWidth)

2016年3月17日 (木)

VB.NETのComboBoxに枠線(ボーダー)を表示する様に拡張したクラス(Border/BorderStyle/BorderWidth)

VB.NETの ComboBox には枠線(ボーダー)を表示するプロパティが標準ではありません。
ComboBox の FlatStyle を Flat に設定すると、枠線が白色になりよく見えなくなります。そこで、 ComboBox の拡張クラスを、枠線の色、枠線の種類、枠線の幅を追加のプロパティとして作成しました。クラス名は名前は ComboBoxFrm とします。

以下に ComboBoxFrm クラスのソースを示します。

ウインドウメッセージの処理の中で、 WM_PAINT のタイミングでコンボボックスコントロールの枠を描画しています。
描画にはControlPaintクラスの静的メンバとして用意されている DrawBorder メソッドを使います。
尚、枠線の幅は大きすぎても変な表示になりますので、３までに抑えてあります。

Imports System.ComponentModel
Imports System.Windows.Forms

Public Class ComboBoxFrm
    Inherits System.Windows.Forms.ComboBox
    Private Const WM_PAINT As Integer = &HF

Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        MyBase.WndProc(m)
        Select Case m.Msg
            Case WM_PAINT
                Call DrawRectangle()
        End Select
    End Sub

Private Sub DrawRectangle()
        Try
            'ボタンスタイルコントロールの輪郭の描画(線の幅指定有り)
            ControlPaint.DrawBorder(Me.CreateGraphics(), Me.ClientRectangle, _
                                    Me.BorderColor, Me.BorderWidth, Me.BorderStyle, _
                                    Me.BorderColor, Me.BorderWidth, Me.BorderStyle, _
                                    Me.BorderColor, Me.BorderWidth, Me.BorderStyle, _
                                    Me.BorderColor, Me.BorderWidth, Me.BorderStyle)
        Catch
        End Try
    End Sub

Private _BorderColor As Color = System.Drawing.SystemColors.ControlText
    <Category("表示")>
    Public Property BorderColor() As Color
        Get
            Return Me._BorderColor
        End Get
        Set(ByVal value As Color)
            Me._BorderColor = value
        End Set
    End Property

Private _BorderStyle As ButtonBorderStyle = ButtonBorderStyle.None
    <Category("表示")>
    Public Property BorderStyle() As ButtonBorderStyle
        Get
            Return Me._BorderStyle
        End Get
        Set(ByVal value As ButtonBorderStyle)
            Me._BorderStyle = value
        End Set
    End Property

Private _BorderWidth As Integer = 1
    <Category("表示")>
    Public Property BorderWidth() As Integer
        Get
            Return Me._BorderWidth
        End Get
        Set(ByVal value As Integer)
            If value < 0 Then value = 1
            If value > 3 Then value = 3
            Me._BorderWidth = value
        End Set
    End Property
End Class

このクラスをフォームに張り付けた時のプロパティのウインドウは以下の様な表示になります。